
# config/accessor star-import was dead — dropped (ADR-025 Phase 3 Layer 2).

export def env_file_providers [
  filepath: string
] {
  if not ($filepath | path exists) { return [] }
  (open $filepath | lines | find 'provisioning/providers/' |
     each {|it|
       let parts = ($it | split row 'providers/')
       if ($parts | length) > 1 { $parts | get 1 | str replace '/nulib' '' } else { null }
     }
  )
}
export def install_config [
    ops: string
    provisioning_cfg_name: string = "provisioning"
    --context
] {
  $env.PROVISIONING_DEBUG = ($env | get PROVISIONING_DEBUG? | default false | into bool)
  let reset = ($ops | str contains "reset")
  let use_context = if ($ops | str contains "context") or $context { true } else { false }
  let provisioning_config_path = $nu.default-config-dir | path dirname | path join $provisioning_cfg_name | path join "nushell"
  let provisioning_root = if ((get-config-base-path) | is-not-empty) {
    (get-config-base-path)
  } else {
    let base_path  =  if ($env.PROCESS_PATH | str contains "provisioning") {
      $env.PROCESS_PATH
    } else {
      $env.PWD
    }
    let parts = ($base_path | split row "provisioning")
    $"((if ($parts | is-empty) { "" } else { $parts | first }))provisioning"
  }
  let shell_dflt_template = $provisioning_root | path join "templates"| path join "nushell" | path join "default"
  if not ($shell_dflt_template | path exists) {
    _print $"🛑 Template path (_ansi red_bold)($shell_dflt_template)(_ansi reset) not found"
    exit 1
  }
  let context_filename = "default_context.yaml"
  let context_template = $provisioning_root | path join "templates"| path join $context_filename
  let provisioning_context_path = ($nu.default-config-dir | path dirname | path join $provisioning_cfg_name | path join $context_filename)
  let op = if (is-debug-enabled) { "v" } else { "" }
  if $reset {
    if ($provisioning_context_path | path exists) {
      rm -rf $provisioning_context_path
      _print $"Restore context (_ansi default_dimmed) ($provisioning_context_path)(_ansi reset)"
    }
    if not $use_context and ($provisioning_config_path | path exists) {
      rm -rf $provisioning_config_path
      _print $"Restore defaults (_ansi default_dimmed) ($provisioning_config_path)(_ansi reset)"
    }
  }
  if ($provisioning_context_path | path exists) {
    _print $"Intallation on (_ansi yellow)($provisioning_context_path)(_ansi reset) (_ansi purple_bold)already exists(_ansi reset)"
    _print $"use (_ansi purple_bold)provisioning context(_ansi reset) to manage context \(create, default, set, etc\)"
  } else {
    mkdir ($provisioning_context_path | path dirname)
    let data_context = (open -r $context_template)
    $data_context | str replace "HOME" $nu.home-dir |  save $provisioning_context_path
    #$use_context | update infra_path ($context.infra_path | str replace "HOME" $nu.home-dir) |  save $provisioning_context_path
    _print $"Intallation on (_ansi yellow)($provisioning_context_path) (_ansi green_bold)completed(_ansi reset)"
    _print $"use (_ansi purple_bold)provisioning context(_ansi reset) to manage context \(create, default, set, etc\)"
  }
  if ($provisioning_config_path | path exists) {
    _print $"Intallation on (_ansi yellow)($provisioning_config_path)(_ansi reset) (_ansi purple_bold)already exists(_ansi reset)"
    _print ( $"with library path in (_ansi default_dimmed)env.nu(_ansi reset) for: " +
      $" (_ansi blue)(env_file_providers $"($provisioning_config_path)/env.nu" | str join ' ')(_ansi reset)"
    )
  } else {
    mkdir $provisioning_config_path
    mut providers_lib_paths = $provisioning_root | path join "providers"
    mut providers_list = ""
    for it in (ls $"($provisioning_root)/providers" | get name)  {
      #if not ($"($it)/templates" | path exists) { continue }
      if not ($"($it)/nulib" | path exists) { continue }
      if $providers_list != "" { $providers_list += " " }
      $providers_list += ($it | path basename)
      if $providers_lib_paths != "" { $providers_lib_paths += "\n    " }
      $providers_lib_paths += ($it | path join "nulib")
    }
    ^cp $"-p($op)r" ...(glob $"($shell_dflt_template)/*") $provisioning_config_path
    if ($provisioning_config_path | path join "env.nu" | path exists) {
      ( open ($provisioning_config_path | path join "env.nu") -r |
        str replace "# PROVISIONING_NULIB_DIR" ($provisioning_root | path join "core"| path join "nulib") |
        str replace "# PROVISIONING_NULIB_PROVIDERS" $providers_lib_paths |
        save -f $"($provisioning_config_path)/env.nu"
      )
      _print $"providers libs added for: (_ansi blue)($providers_list)(_ansi reset)"
    }
    _print $"Intallation on (_ansi yellow)($provisioning_config_path) (_ansi green_bold)completed(_ansi reset)"
  }
}
